HoverHandler QML Type

Handler for mouse and tablet hover. 更多...

import 语句：	import QtQuick
继承：	SinglePointHandler

所有成员列表，包括继承成员

特性

acceptedDevices : flags
acceptedModifiers : flags
acceptedPointerTypes : flags
active : bool
blocking : bool
cursorShape : Qt::CursorShape
enabled : bool
grabPermissions : flags
hovered : bool
margin : real
parent : Item
point : handlerPoint
target : Item

信号

canceled (eventPoint point )
grabChanged (PointerDevice::GrabTransition transition , eventPoint point )

详细描述

HoverHandler detects a hovering mouse or tablet stylus cursor.

A binding to the hovered property is the easiest way to react when the cursor enters or leaves the parent Item. The point property provides more detail, including the cursor position. The acceptedDevices , acceptedPointerTypes ，和 acceptedModifiers properties can be used to narrow the behavior to detect hovering of specific kinds of devices or while holding a modifier key.

The cursorShape property allows changing the cursor whenever hovered changes to true .

另请参阅 MouseArea , PointHandler ，和 Pointer Handlers Example .

特性文档编制

acceptedDevices : flags

The types of pointing devices that can activate the pointer handler.

默认情况下，此特性被设为 PointerDevice.AllDevices . If you set it to an OR combination of device types, it will ignore pointer events from the non-matching devices.

For example, an item could be made to respond to mouse hover in one way, and stylus hover in another way, with two handlers:

import QtQuick
Rectangle {
    width: 150; height: 50; radius: 3
    color: mouse.hovered ? "goldenrod" : stylus.hovered ? "tomato" : "wheat"
    HoverHandler {
        id: stylus
        acceptedDevices: PointerDevice.Stylus
        cursorShape: Qt.CrossCursor
    }
    HoverHandler {
        id: mouse
        acceptedDevices: PointerDevice.Mouse
        cursorShape: Qt.PointingHandCursor
    }
}

The available device types are as follows:

常量	描述
`PointerDevice.Mouse`	鼠标。
`PointerDevice.TouchScreen`	A touchscreen.
`PointerDevice.TouchPad`	A touchpad or trackpad.
`PointerDevice.Stylus`	A stylus on a graphics tablet.
`PointerDevice.Airbrush`	An airbrush on a graphics tablet.
`PointerDevice.Puck`	A digitizer with crosshairs, on a graphics tablet.
`PointerDevice.AllDevices`	Any type of pointing device.

另请参阅 QInputDevice::DeviceType .

acceptedModifiers : flags

If this property is set, a hover event is handled only if the given keyboard modifiers are pressed. The event is ignored without the modifiers.

This property is set to Qt.KeyboardModifierMask by default, resulting in handling hover events regardless of any modifier keys.

For example, an Item could have two handlers of the same type, one of which is enabled only if the required keyboard modifiers are pressed:

import QtQuick
Rectangle {
    width: 150; height: 50; radius: 3
    color: control.hovered ? "goldenrod" : shift.hovered ? "wheat" : "beige"
    HoverHandler {
        id: control
        acceptedModifiers: Qt.ControlModifier
        cursorShape: Qt.PointingHandCursor
    }
    HoverHandler {
        id: shift
        acceptedModifiers: Qt.ShiftModifier
        cursorShape: Qt.CrossCursor
    }
}

The available modifiers are as follows:

常量	描述
`Qt.NoModifier`	No modifier key is allowed.
`Qt.ShiftModifier`	A Shift key on the keyboard must be pressed.
`Qt.ControlModifier`	A Ctrl key on the keyboard must be pressed.
`Qt.AltModifier`	An Alt key on the keyboard must be pressed.
`Qt.MetaModifier`	A Meta key on the keyboard must be pressed.
`Qt.KeypadModifier`	A keypad button must be pressed.
`Qt.GroupSwitchModifier`	A Mode_switch key on the keyboard must be pressed. X11 only (unless activated on Windows by a command line argument).
`Qt.KeyboardModifierMask`	The handler ignores modifier keys.

另请参阅 Qt::KeyboardModifier .

acceptedPointerTypes : flags

The types of pointing instruments (generic, stylus, eraser, and so on) that can activate the pointer handler.

默认情况下，此特性被设为 PointerDevice.AllPointerTypes . If you set it to an OR combination of device types, it will ignore events from non-matching events.

For example, you could provide feedback by changing the cursor depending on whether a stylus or eraser is hovering over a graphics tablet:

import QtQuick
Rectangle {
    id: rect
    width: 150; height: 150
    HoverHandler {
        id: stylus
        acceptedPointerTypes: PointerDevice.Pen
        cursorShape: Qt.CrossCursor
    }
    HoverHandler {
        id: eraser
        acceptedPointerTypes: PointerDevice.Eraser
        cursorShape: Qt.BlankCursor
        target: Image {
            parent: rect
            source: "images/cursor-eraser.png"
            visible: eraser.hovered
            x: eraser.point.position.x
            y: eraser.point.position.y - 32
        }
    }
}

The available pointer types are as follows:

常量	描述
`PointerDevice.Generic`	A mouse or a device that emulates a mouse.
`PointerDevice.Finger`	A finger on a touchscreen (hover detection is unlikely).
`PointerDevice.Pen`	A stylus on a graphics tablet.
`PointerDevice.Eraser`	An eraser on a graphics tablet.
`PointerDevice.Cursor`	A digitizer with crosshairs, on a graphics tablet.
`PointerDevice.AllPointerTypes`	Any type of pointing device.

另请参阅 QPointingDevice::PointerType .

[read-only] active : bool

This holds true whenever this Input Handler has taken sole responsibility for handing one or more eventPoints , by successfully taking an exclusive grab of those points. This means that it is keeping its properties up-to-date according to the movements of those eventPoints and actively manipulating its target (if any).

[since 6.3] blocking : bool

Whether this handler prevents other items or handlers behind it from being hovered at the same time. This property is false 在默认情况下。

This property was introduced in Qt 6.3.

cursorShape : Qt::CursorShape

This property holds the cursor shape that will appear whenever hovered is true and no other handler is overriding it.

The available cursor shapes are:

Qt.ArrowCursor
Qt.UpArrowCursor
Qt.CrossCursor
Qt.WaitCursor
Qt.IBeamCursor
Qt.SizeVerCursor
Qt.SizeHorCursor
Qt.SizeBDiagCursor
Qt.SizeFDiagCursor
Qt.SizeAllCursor
Qt.BlankCursor
Qt.SplitVCursor
Qt.SplitHCursor
Qt.PointingHandCursor
Qt.ForbiddenCursor
Qt.WhatsThisCursor
Qt.BusyCursor
Qt.OpenHandCursor
Qt.ClosedHandCursor
Qt.DragCopyCursor
Qt.DragMoveCursor
Qt.DragLinkCursor

The default value of this property is not set, which allows any active handler on the same parent item to determine the cursor shape. This property can be reset to the initial condition by setting it to undefined .

If any handler with defined cursorShape is active , that cursor will appear. Else if the HoverHandler has a defined cursorShape , that cursor will appear. Otherwise, the cursor of parent item will appear.

注意： When this property has not been set, or has been set to undefined , if you read the value it will return Qt.ArrowCursor .

另请参阅 Qt::CursorShape and QQuickItem::cursor ().

enabled : bool

若 PointerHandler is disabled, it will reject all events and no signals will be emitted.

grabPermissions : flags

This property specifies the permissions when this handler's logic decides to take over the exclusive grab, or when it is asked to approve grab takeover or cancellation by another handler.

常量	描述
`PointerHandler.TakeOverForbidden`	This handler neither takes from nor gives grab permission to any type of Item or Handler.
`PointerHandler.CanTakeOverFromHandlersOfSameType`	This handler can take the exclusive grab from another handler of the same class.
`PointerHandler.CanTakeOverFromHandlersOfDifferentType`	This handler can take the exclusive grab from any kind of handler.
`PointerHandler.CanTakeOverFromItems`	This handler can take the exclusive grab from any type of Item.
`PointerHandler.CanTakeOverFromAnything`	This handler can take the exclusive grab from any type of Item or Handler.
`PointerHandler.ApprovesTakeOverByHandlersOfSameType`	This handler gives permission for another handler of the same class to take the grab.
`PointerHandler.ApprovesTakeOverByHandlersOfDifferentType`	This handler gives permission for any kind of handler to take the grab.
`PointerHandler.ApprovesTakeOverByItems`	This handler gives permission for any kind of Item to take the grab.
`PointerHandler.ApprovesCancellation`	This handler will allow its grab to be set to null.
`PointerHandler.ApprovesTakeOverByAnything`	This handler gives permission for any type of Item or Handler to take the grab.

默认为 PointerHandler.CanTakeOverFromItems | PointerHandler.CanTakeOverFromHandlersOfDifferentType | PointerHandler.ApprovesTakeOverByAnything which allows most takeover scenarios but avoids e.g. two PinchHandlers fighting over the same touchpoints.

[read-only] hovered : bool

Holds true whenever any pointing device cursor (mouse or tablet) is within the bounds of the parent Item, extended by the margin ，若有的话。

margin : real

The margin beyond the bounds of the parent item within which an eventPoint can activate this handler. For example, on a PinchHandler 在哪里 target is also the parent , it's useful to set this to a distance at least half the width of a typical user's finger, so that if the parent has been scaled down to a very small size, the pinch gesture is still possible. Or, if a TapHandler -based button is placed near the screen edge, it can be used to comply with Fitts's Law: react to mouse clicks at the screen edge even though the button is visually spaced away from the edge by a few pixels.

默认值为 0。

parent : Item

The Item which is the scope of the handler; the Item in which it was declared. The handler will handle events on behalf of this Item, which means a pointer event is relevant if at least one of its eventPoints occurs within the Item's interior. Initially target() is the same, but it can be reassigned.

注意： When a handler is declared in a QtQuick3D.Model object, the parent is not an Item, therefore this property is null .

另请参阅 target and QObject::parent ().

[read-only] point : handlerPoint

The eventPoint currently being handled. When no point is currently being handled, this object is reset to default values (all coordinates are 0).

target : Item

The Item which this handler will manipulate.

By default, it is the same as the parent , the Item within which the handler is declared. However, it can sometimes be useful to set the target to a different Item, in order to handle events within one item but manipulate another; or to null , to disable the default behavior and do something else instead.

信号文档编制

canceled ( eventPoint point )

If this handler has already grabbed the given point , this signal is emitted when the grab is stolen by a different Pointer Handler or Item.

注意： 相应处理程序是 onCanceled .

grabChanged ( PointerDevice::GrabTransition transition , eventPoint point )

This signal is emitted when the grab has changed in some way which is relevant to this handler.

The transition (verb) tells what happened. The point (object) is the point that was grabbed or ungrabbed.

注意： 相应处理程序是 onGrabChanged .