WebEngineAction QML 类型

An action that represents a WebEngineView::WebAction . 更多...

导入语句：	import QtWebEngine
Since:	QtWebEngine 1.8

所有成员列表，包括继承成员

特性

enabled : bool
iconName : string
text : int

方法

void trigger ()

详细描述

A WebEngineAction is returned by the WebEngineView::action () method. It provides information about the action, such as whether it is enabled .

The following code uses the WebEngineView::action () method to check if the copy action is enabled:

var copyAction = webEngineView.action(WebEngineView.Copy);
if (copyAction.enabled)
    console.log("Copy is enabled.");
else
    console.log("Copy is disabled.");

A ToolButton can be connected to a WebEngineAction as follows:

            ToolButton {
                property int itemAction: WebEngineView.Back
                text: webEngineView.action(itemAction).text
                enabled: webEngineView.action(itemAction).enabled
                onClicked: webEngineView.action(itemAction).trigger()
                icon.name: webEngineView.action(itemAction).iconName
                display: AbstractButton.TextUnderIcon
            }

A context menu could be implemented like this:

        property Menu contextMenu: Menu {
            Repeater {
                model: [
                    WebEngineView.Back,
                    WebEngineView.Forward,
                    WebEngineView.Reload,
                    WebEngineView.SavePage,
                    WebEngineView.Copy,
                    WebEngineView.Paste,
                    WebEngineView.Cut,
                    WebEngineView.ChangeTextDirectionLTR,
                    WebEngineView.ChangeTextDirectionRTL,
                ]
                MenuItem {
                    text: webEngineView.action(modelData).text
                    enabled: webEngineView.action(modelData).enabled
                    onClicked: webEngineView.action(modelData).trigger()
                    icon.name: webEngineView.action(modelData).iconName
                    display: MenuItem.TextBesideIcon
                }
            }
        }
        onContextMenuRequested: function(request) {
            if (customContextMenuOption.checked) {
                request.accepted = true;
                contextMenu.popup();
            }
        }

特性文档编制

[read-only] enabled : bool

This property holds whether the action is enabled.

[read-only] iconName : string

This property holds the name of the icon for the action. This name can be used to pick the icon from a theme.

[read-only] text : int

This property holds a textual description of the action.

方法文档编制

void trigger ()

Triggers the action.