Missing property

This warning category is spelled [missing-property] by qmllint.

Can't assign to non-existent default property

What happened?

You assigned an object to a non-existing default property.

Why is this bad?

The QML engine can't assign this object at runtime.

范例

import QtQuick
Item {
    component MyType: QtObject { property Item myItem; }
    MyType {
        Item {}
    }
}
					

To fix this warning, specify the property you want to bind to or, if you are the author of the type, mark a property as default:

import QtQuick
Item {
    component MyType: QtObject { property Item myItem; }
    MyType {
        myItem: Item {}
    }
    component AlternativeMyType: QtObject { default property Item myItem; }
    AlternativeMyType {
        Item {} // bound to myItem via default property
    }
}
					

Property does not exist

What happened?

You assigned an expression to a non-existing property.

Why is this bad?

The QML engine can't assign this expression at runtime.

范例

import QtQuick
Item {
    property int myInt
    myItn: 42
}
					

To fix this warning, remove the binding or correct a possible typo:

import QtQuick
Item {
    property int myInt
    myInt: 42
}
					

Member not found on type

What happened?

You accessed a member in a field member expression that can't be found by QML tooling.

A field member expression is an expression of the form someId.someProperty .

Why is this bad?

The QML tooling can't find this member, and the QML engine probably can't either.

范例

import QtQuick
Item {
    id: self
    property int myInt
    property int myInt2: 1 + self.myItn
}
					

To fix this warning, remove the binding or correct a possible typo:

import QtQuick
Item {
    id: self
    property int myInt
    property int myInt2: 1 + self.myInt
}
					

内容

1. Can't assign to non-existent default property

2. What happened?

3. Why is this bad?

4. 范例

5. Property does not exist

6. What happened?

7. Why is this bad?

8. 范例

9. Member not found on type

10. What happened?

11. Why is this bad?

12. 范例